How to get XML content from "above" repeat element?

The repeating element here is not clear - normally you would expect it to be "//service", which gives you all the services as result. If all you are interested in are the services and their attributes, you could use "//service" as repeating element and simply specify that no children of that node should be processed.

Of course this throws away a lot of the data contained in the XML, so that's probably not want you want. The problem here is that each repeating element contains 0 to n child elements - and since each repeating element results in a single MashZone table row, the multiple children have to be put somewhere within that row. MashZone does this by creating additional columns and numbering them (that's why you get those "_0" columns). All data is then contained in the row - though not really usable.

Another approach, which is more complex but also more powerful, is to use the "preprocessing" feature of the XML operator. Essentially, you write a XSLT script that transforms your source XML so that it presents its data in a more MashZone-friendly format. The idea is to iterate over the "consumer" elements and enrich them with the information of their parent elements.

The XSLT script required looks complex but is rather simple for your sample. It restructures the XML so that the column names are a bit different, but makes all the information accessible for MashZone (I'm no real XSLT specialist, so there may be a shorter, more elegant version to achieve this).

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">

  <!-- iterate over the services -->
  <xsl:template match="/">
    <xsl:element name="result">
      <xsl:for-each select="/services">
        <xsl:apply-templates/>
      </xsl:for-each>
    </xsl:element>
  </xsl:template>

   <!-- simply copy all information of the consumers and their details -->
   <xsl:template match="text()|details|totalhits|successHits|avgRespTime|requestPayload|responsePayload">
      <xsl:copy>
         <xsl:apply-templates/>
      </xsl:copy>
   </xsl:template>

   <!-- enrich the consumers with their parents' information -->
   <xsl:template match="consumer">
      <xsl:copy>
         <consName>
            <xsl:value-of select="@consName"/>
         </consName>
         <serviceOwner>
            <xsl:value-of select="../@owner"/>
         </serviceOwner>
        <serviceName>
            <xsl:value-of select="../@name"/>
        </serviceName>
        <serviceUserVer>
            <xsl:value-of select="../@userVer"/>
        </serviceUserVer>
        <xsl:apply-templates/>
      </xsl:copy>
   </xsl:template>

   <!-- add those cases where the service has no consumer -->
   <xsl:template match="service[not(consumer)]">
      <consumer>
         <consName>
         </consName>
         <serviceOwner>
            <xsl:value-of select="@owner"/>
         </serviceOwner>
         <serviceName>
            <xsl:value-of select="@name"/>
         </serviceName>
         <serviceUserVer>
            <xsl:value-of select="@userVer"/>
         </serviceUserVer>
      </consumer>
   </xsl:template>

</xsl:stylesheet>

If you add that XSLT script to the XML operator in the "preprocessing" option, and specify the new repeating element "consumer", the output will look like this:

As you see, nothing is impossible in MashZone...

ok, I was wondering if XSLT was the appropriate approach. (I updated my post - the selection I was using was /services/service/consumer - not /services/service/details). Since I mange the XML source (it is from an XQuery against CentraSite), I could also flatten the structure from there. 

...which is, of course, even better, since it takes a lot of load off MashZone.